【VBA × Outlook】申請書を自動でメール送信する方法｜Excelファイルを添付して一発送信

2024年1月18日2025年12月22日

経緯

Excelで申請書を作成した後、そのままOutlookでメールに添付して送信する作業を毎回手作業で行っていました。
宛先や本文もほぼ毎回同じだったため、**「VBAで自動化できないか？」**と思い、実装してみました。

今回の構成では、L1セルを選択するだけで、Outlookが起動し、申請書を添付したメールが作成される仕組みです。

想定構成

**申請書が記載されたExcelファイル（Sheet1）**がある
Sheet1の セル L1 に「メール送信」と表示されており、ここを選択することで処理が実行される
宛先、CC、件名、本文、添付ファイル（現在のブック）を自動で設定

前準備（Outlookライブラリの有効化）

VBAエディタで以下の設定を行ってください。

ツール → 参照設定 を開く
「Microsoft Outlook XX.X Object Library」にチェックを入れる
「OK」をクリック

※バージョン番号（XX.X）はご使用のOffice環境により異なります（例：16.0）

モジュール側のコード（SendEmail）

標準モジュール（Module1など）に以下のコードを記述します。

Sub SendEmail()

    Dim objOutlook As Outlook.Application
    Dim objMail As Outlook.MailItem
    Dim currentWorkbookPath As String
    Dim ans As Integer

    Set objOutlook = New Outlook.Application
    Set objMail = objOutlook.CreateItem(olMailItem)
    currentWorkbookPath = ThisWorkbook.FullName

    ' メール送信確認メッセージ
    ans = MsgBox("メールを送信しますか", vbYesNo + vbExclamation, "メール送信確認")

    ' 念のため保存
    ActiveWorkbook.Save

    If ans = vbYes Then
        MsgBox "メール内容を確認したら、送信ボタンを押してください。"

        With objMail
            .To = "" ' 宛先を記入
            .CC = "" ' CCを記入（任意）
            .Subject = "申請書"
            .BodyFormat = olFormatPlain
            .Body = "林さん" & vbCrLf & vbCrLf & _
                    "申請書を添付しました。" & vbCrLf & _
                    "よろしくお願いします。" & vbCrLf & vbCrLf & _
                    "森"
            .Attachments.Add currentWorkbookPath
            .Display ' メールを表示（確認したい場合）
            ' .Send ' 確認せずに送信する場合はこちらを有効に
        End With

        Set objOutlook = Nothing

    Else
        MsgBox "メール送信をキャンセルしました。"
    End If

    ' 再保存
    ActiveWorkbook.Save

    ' A1セルにフォーカスを戻す
    ThisWorkbook.Sheets(1).Range("A1").Select

End Sub

トリガー設定（Sheet1のL1セルを選択したときに発動）

次に、VBAエディタで Sheet1 モジュールに以下のコードを追加します。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("L1")) Is Nothing Then
        Call SendEmail
    End If
End Sub