【VBA】CSVファイルをExcelに読み込むマクロ｜コピペ不要の自動化

2024年6月8日2025年12月22日

経緯

これまでCSVファイルの内容をExcelに貼り付ける際、手作業でコピペしていたのですが、
毎回繰り返すのが手間に感じていたため、VBAでCSVファイルを直接読み込むマクロを作成しました。

特に、CSV形式で出力されるデータベースファイルを取り扱う場面で、自動で読み込める仕組みがあると非常に効率的です。

実装したVBAコード

以下は、CSVファイルを選択し、その内容をアクティブなシートに自動的に読み込むマクロです。
あわせて、既存データを全削除するクリア処理も付け加えています。

CSV読み込みマクロ

Sub ImportCSVFile()
    Dim fd As FileDialog
    Set fd = Application.FileDialog(msoFileDialogFilePicker)
    Dim csvFilePath As String
    Dim targetSheet As Worksheet

    With fd
        .Title = "Select a CSV File"
        .Filters.Clear
        .Filters.Add "CSV Files", "*.csv"
        .AllowMultiSelect = False
        If .Show = True Then
            csvFilePath = .SelectedItems(1)
        Else
            MsgBox "No file selected."
            Exit Sub
        End If
    End With

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    Set targetSheet = ActiveSheet

    Dim fileNum As Integer
    Dim lineContent As String
    Dim lineArray() As String
    Dim rowNum As Long
    Dim colNum As Long

    fileNum = FreeFile
    Open csvFilePath For Input As #fileNum

    rowNum = 1
    Do Until EOF(fileNum)
        Line Input #fileNum, lineContent
        lineArray = Split(lineContent, ",")
        For colNum = LBound(lineArray) To UBound(lineArray)
            targetSheet.Cells(rowNum, colNum + 1).Value = lineArray(colNum)
        Next colNum
        rowNum = rowNum + 1
    Loop

    Close #fileNum

    Application.ScreenUpdating = True
    Application.EnableEvents = True

    MsgBox "File has been imported successfully."
End Sub

アクティブシートの内容をクリアするマクロ

Sub ClearActiveSheet()
    Dim ws As Worksheet
    Set ws = ActiveSheet

    Application.ScreenUpdating = False
    Application.EnableEvents = False

    ws.Cells.ClearContents

    Application.ScreenUpdating = True
    Application.EnableEvents = True

    MsgBox "All data has been cleared from the active sheet."
End Sub