【Excel VBA】散布図の線の色を変更する｜ボタンとカラーパレットで直感操作

2024年5月19日2026年1月13日

経緯

Excel VBAで複数のグラフを扱っている中で、
**「特定の系列だけ線の色を変えたい」**という場面がありました。
とくに、グラフが多くなってくると、マウス操作で色を変えるのは非効率です。

そこで今回は、VBAで「セルの値に該当する系列名の線だけ色を変更する」処理をボタンひとつで実現しました。

実現したい仕様

Sheet1 に多数の散布図が配置されている
セル A1 に「NO1」「NO2」「NO3」など、系列名が入力されている
「色変更」ボタン（図形）を押すとカラーパレットが表示され、選択した色で該当系列の線色が変更される
ボタン（図形）の枠線の色も選んだ色に変更される

事前準備

カラーパレットの表示には Windows API を使用します
マクロを登録する図形（「色変更」ボタン）をあらかじめ配置しておいてください

実装コード（VBA）

以下のコードを 標準モジュール に貼り付けてください。

1. Windows API とカラーダイアログの定義

Private Type CHOOSECOLOR
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    rgbResult As Long
    lpCustColors As String
    Flags As Long
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type

Private Declare Function ChooseColor Lib "comdlg32.dll" Alias "ChooseColorA" (pChoosecolor As CHOOSECOLOR) As Long
Private Declare Function OleTranslateColor Lib "oleaut32.dll" (ByVal lOleColor As Long, ByVal lpPal As Long, lpColorRef As Long) As Long

Const CC_RGBINIT = &H1&
Const CC_FULLOPEN = &H2&

Private Function ShowColorDialog(Optional ByVal DefaultColor As Long = 0) As Long
    Dim cc As CHOOSECOLOR
    Dim CustColors As String

    CustColors = String$(16 * 4, 0)
    With cc
        .lStructSize = Len(cc)
        .hwndOwner = Application.hwnd
        .Flags = CC_RGBINIT Or CC_FULLOPEN
        .rgbResult = DefaultColor
        .lpCustColors = CustColors
    End With

    If ChooseColor(cc) Then
        ShowColorDialog = cc.rgbResult
    Else
        ShowColorDialog = -1
    End If
End Function

2. 色を選択して該当系列の線色を変更する処理

Sub Change_the_ColorLine()
    Dim ws As Worksheet
    Dim chartObj As ChartObject
    Dim ser As Series
    Dim targetName As String
    Dim selectedColor As Long
    Dim shp As Shape

    Set ws = ThisWorkbook.Sheets("Sheet1")
    targetName = ws.Range("A1").Value

    selectedColor = ShowColorDialog
    If selectedColor = -1 Then Exit Sub

    ' 各グラフの対象系列の線色を変更
    For Each chartObj In ws.ChartObjects
        For Each ser In chartObj.Chart.FullSeriesCollection
            If ser.Name = targetName Then
                ser.Format.Line.ForeColor.RGB = selectedColor
            End If
        Next ser
    Next chartObj

    ' ボタン自身の枠線の色を変更
    Set shp = ActiveSheet.Shapes(Application.Caller)
    shp.Line.ForeColor.RGB = selectedColor
End Sub