【VBA】リストにある名前をテーブルに羅列したい【Word】

2023年12月1日2023年12月19日

経緯

WindowsのWordで書類を書いてました。

書類にはテーブルがあり、日付と担当者が以下のようになっています。

日付	担当者
11月27日	森
12月1日
12月11日
12月22日
12月29日
1月7日
1月13日
1月20日

名前のリストを作って、担当者の列に次々羅列するコードを勉強してました。

コード

以下はコードです。

“2,2”セルの内容を変更せずに、3行目の2列目から名前リストを開始してテーブルを更新します。リストの最後に達したら、最初に戻ります。

Sub PopulateNamesInTableKeepingSecondCellName()
    Dim doc As Document
    Set doc = ActiveDocument

    Dim tbl As Table
    Set tbl = doc.Tables(1) ' 最初のテーブルを選択

    ' 名前のリスト
    Dim names As Variant
    names = Array("森", "小森", "中森", "大森", "林", "小林", "中林", "大林")

    ' "2,2"セルの文字列を取得し、末尾の改行文字を削除
    Dim currentName As String
    currentName = tbl.Cell(2, 2).Range.Text
    currentName = Trim(Left(currentName, Len(currentName) - 2))

    ' 現在の名前の次の名前から開始
    Dim startIndex As Integer
    startIndex = -1 ' 初期値は-1としておく
    Dim i As Integer
    For i = LBound(names) To UBound(names)
        If names(i) = currentName Then
            startIndex = (i + 1) Mod (UBound(names) + 1)
            Exit For
        End If
    Next i

    ' 名前をテーブルの2列目の3行目から挿入
    If startIndex <> -1 Then
        For i = 3 To tbl.Rows.Count
            tbl.Cell(i, 2).Range.Text = names(startIndex)
            startIndex = (startIndex + 1) Mod (UBound(names) + 1)
        Next i
    Else
        MsgBox "テーブルの2行目2列目の内容が名前リストに見つかりません。"
    End If
End Sub

という感じです。

参考になれば、幸いです。

ここまで読んでいただきありがとうございました。